背景の追加

高さの判定

• 一番近い高さに移動させる
• 高さが違いすぎたら元に戻す

new MovieMaterial(MovieClip参照, false, true, false, new Rectangle(0, 0, 256, 256));

//meshはTriangleMesh3Dオブジェクトです
for each(var face:Triangle3D in mesh.geometry.faces) {
	for each(var uv:NumberUV in face.uv) {
		uv.v -= 0.05;
	}
}

• UV値が大きくなりすぎなければいい
• UV値が0～1の間に収まっていれば問題なさそう
• じゃあuv0.v = (uv0.v + 0.1)%1;とかやれば解決？
• でもこれやると3つのuv座標の位置関係が崩れてテクスチャが反転したりするから駄目
• じゃあ3つのuv値それぞれの初期値+オフセット値として、オフセット値を0～1に収めればいい
• それには全三角ポリゴンの全UV値を最初に保存しておく必要がある
• しかもスライドさせる時にどのUV値がどの初期値なのか調べる必要もある

package {
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.utils.Dictionary;
	import org.papervision3d.core.geom.renderables.Triangle3D;
	import org.papervision3d.core.geom.TriangleMesh3D;
	import org.papervision3d.core.math.NumberUV;
	import org.papervision3d.materials.BitmapMaterial;
	/**
	 * ポリゴンのUV値をスライドさせてテクスチャを動かします。
	 * Papervision3D ver2.1.920で使えます。
	 */
	public class TextureSlider {
		private var faces:Dictionary;
		private var models:Dictionary;
		private var materials:Dictionary;
		private var sp:Sprite;
		//コンストラクタ
		public function TextureSlider() {
			sp = new Sprite();
			faces = new Dictionary();
			models = new Dictionary();
			materials = new Dictionary();
		}
		/**
		 * スライド対象のBitmapMaterialを登録します（登録しないとスライドしても見た目が変化しません）
		 * @param	bitmap
		 */
		public function addMaterial(bitmap:BitmapMaterial):void {
			materials[bitmap] = bitmap;
		}
		/**
		 * テクスチャをスライドさせるモデルを指定します
		 * @param	model	テクスチャをスライドさせたいモデル
		 * @param	speedU	1フレームで変化するU軸方向のスライド値
		 * @param	speedV	1フレームで変化するV軸方向のスライド値
		 */
		public function addModel(model:TriangleMesh3D, speedU:Number, speedV:Number):void {
			if (models[model] != null) return;
			models[model] = { slideU:0, slideV:0, speedU:speedU, speedV:speedV, target:model };
			for each(var face:Triangle3D in model.geometry.faces) faces[face] = { uvs:[face.uv0.clone(), face.uv1.clone(), face.uv2.clone()] };
		}
		/**
		 * 登録情報破棄＆スライド停止
		 */
		public function dispose():void {
			faces = new Dictionary();
			models = new Dictionary();
			materials = new Dictionary();
			stopSlide();
		}
		/**
		 * スライド開始
		 */
		public function startSlide():void {
			sp.addEventListener(Event.ENTER_FRAME, onEnter);
		}
		/**
		 * スライドを停止
		 */
		public function stopSlide():void {
			sp.removeEventListener(Event.ENTER_FRAME, onEnter);
		}
		/**
		 * 1回スライドさせる
		 */
		public function stepSlide():void {
			for each(var m:Object in models) {
				m.slideU = (m.slideU + m.speedU) % 1;
				m.slideV = (m.slideV + m.speedV) % 1;
				for each(var face:Triangle3D in m.target.geometry.faces) {
					var fdata:Object = faces[face];
					for (var i:int = 0; i <= 2; i++ ) {
						face.uv[i].u = fdata.uvs[i].u + m.slideU;
						face.uv[i].v = fdata.uvs[i].v + m.slideV;
					}
				}
			}
			for each(var bm:BitmapMaterial in materials) if (bm != null) bm.resetMapping();
		}
		//毎フレーム処理
		private function onEnter(e:Event):void {
			stepSlide();
		}
	}	
}

//plane1とplane2がマテリアルをスライドさせたいモデル
//map1とmap2がモデルに貼ってあるBitmapMaterial
var slider:TextureSlider = new TextureSlider();
slider.addModel(plane1, 0, 0.02);
slider.addModel(plane2, 0, 0.02);
slider.addMaterial(map1);
slider.addMaterial(map2);
slider.startSlide();

やってる事

1. 三角ポリゴンを包むAABBを求める(動かないなら最初の1回だけ)
2. 視線ベクトルが長さを持っていたら視線のAABBと1を交差判定⇒判定なしで交差なし
3. 1のAABBと視線ベクトル(直線)を交差判定⇒判定なしで交差なし
4. 最後は今まで通り視線と三角ポリゴンを交差判定

/**
 * (※追記)ASのコードはもうすこし検証してから載せ直すことにしました。
 */

処理落ちの原因

キャラクターモデル

Colladaファイルの書き出し

• 書き出し形式
  

• 書き出しオプション
  

• daeファイル内の個人情報

• サーバーにあげると画像マテリアルが表示できない

キャラクターアニメーション

import org.papervision3d.core.math.Matrix3D;
import org.papervision3d.objects.DisplayObject3D;
/**
 * オブジェクトのワールド空間での変形情報を取得
 * @param	obj	
 * @return
 */
public static function getWorldTransform(obj:DisplayObject3D):Matrix3D {
	obj.updateTransform();
	var res:Matrix3D = new Matrix3D();
	res.copy(obj.transform);
	var parent3D:DisplayObject3D = obj.parent as DisplayObject3D;
	if (parent3D != null) res.calculateMultiply(getWorldTransform(parent3D), res);
	return res;
}

import org.papervision3d.core.math.Number3D;
/**
 * レイが三角ポリゴンに当たっているかチェック(ポリゴンは頂点反時計周りで構成)
 * @param	pos	レイ放射開始地点
 * @param	vec	レイの方向
 * @param	p0	三角ポリゴンの頂点1
 * @param	p1	三角ポリゴンの頂点2
 * @param	p2	三角ポリゴンの頂点3
 * @param	isDoubleSided	裏向きのポリゴンも交差判定する
 * @return
 */
public function collideRayToTriangle(pos:Number3D, vec:Number3D, p0:Number3D, p1:Number3D, p2:Number3D, isDoubleSided:Boolean = false):Object {
	//レイの方向（正規化）
	var v:Number3D = vec.clone();
	v.normalize();
	//法線ベクトル
	var normal:Number3D = Number3D.cross(Number3D.sub(p1, p0), Number3D.sub(p2, p0));
	normal.normalize();
	var vn:Number = Number3D.dot(v, normal);
	//1.平面と平行なら交差なし(計算誤差を考慮)
	//2.片面チェックON時に視線と法線が同じ向き（裏側を見ている）なら交差なし
	if (Math.abs(vn) < 0.0000001 || (vn > 0 && !isDoubleSided)) return null;
	var xpn:Number = Number3D.dot(Number3D.sub(pos, p0), normal);
	var distance:Number = -xpn / vn;
	//交差位置が視線と逆方向なら交差なし
	if (distance < 0) return null;
	//視線と平面との交点
	var hit:Number3D = v.clone();
	hit.multiplyEq(distance);
	hit.plusEq(pos);
	//交点が三角形内にあるかチェック(計算誤差を考慮)
	var cross0:Number3D = Number3D.cross(Number3D.sub(hit, p0), Number3D.sub(p1, p0));
	if (Number3D.dot(cross0, normal) > 0.000000001) return null;
	var cross1:Number3D = Number3D.cross(Number3D.sub(hit, p1), Number3D.sub(p2, p1));
	if (Number3D.dot(cross1, normal) > 0.000000001) return null;
	var cross2:Number3D = Number3D.cross(Number3D.sub(hit, p2), Number3D.sub(p0, p2));
	if (Number3D.dot(cross2, normal) > 0.000000001) return null;
	var res:Object = new Object();
	res.position = hit;
	res.distance = distance;
	return res;
}

• 頂点ローカル座標にそのモデルの回転･移動･スケールを適用すればワールド座標になる
• モデルの最終的な回転･移動･スケールはDisplayObject3D.world（Matrix3Dクラス）で調べられる
• Matrix3D.multiplyVector(Matrix3D, Number3D);でNumber3Dに変形後の座標が適用される

import org.papervision3d.core.geom.renderables.Triangle3D;
import org.papervision3d.core.geom.TriangleMesh3D;
import org.papervision3d.core.math.Matrix3D;
import org.papervision3d.core.math.Number3D;
/**
 * 視線とメッシュの交差判定をする
 * @param	pos	レイ放射地点
 * @param	vec	レイの方向
 * @param	mesh	メッシュオブジェクト
 * @param	isDoubleSided	裏向きのポリゴンも交差判定する
 * @return
 */
public function collideRayToMesh(pos:Number3D, vec:Number3D, mesh:TriangleMesh3D, isDoubleSided:Boolean = false):Array {
	var res:Array = new Array();
	for each(var face:Triangle3D in mesh.geometry.faces) {
		var ps:Array = new Array();
		for (var i:int = 0; i < 3; i++) {
			var n:Number3D = face["v" + String(i)].toNumber3D();
			//ここでnをワールド座標に変換
			Matrix3D.multiplyVector(mesh.world, n);
			ps.push(n);
		}
		var hit:Object = collideRayToTriangle(pos, vec, ps[0], ps[1], ps[2], isDoubleSided);
		if (hit != null) {
			hit.triangle = face;
			res.push(hit);
		}
	}
	res.sortOn("distance", Array.NUMERIC);
	return res;
}

//交差チェック(結果の配列が0なら交差なし)
var list:Array = collideRayToMesh(pos, vec, mesh, isDoubleSided);
//最初に交差した三角ポリゴン(Triangle3D)の参照
trace(list[0].triangle);
//最初の交差点までの距離(Number)
trace(list[0].distance);
//最初の交差点の座標(Number3D)
trace(list[0].position);